#!/bin/zsh
# Metis Meet (MeetingRecorder.app) v1.6 installer for macOS 15+ (Apple Silicon)
# Usage: curl -fsSL https://metismeet.com/install.sh | zsh
set -euo pipefail

VERSION="1.6"
ARCHIVE_URL="https://metismeet.com/downloads/MetisMeet-1.6-arm64.zip"
EXPECTED_SHA256="fb16ab2a02e35f96eca44eb2b0723de7cc2d0cf2a3cf7dafe34fedac580aa1cb"
APP_NAME="MeetingRecorder.app"

if [[ "$(uname -s)" != "Darwin" ]]; then
  echo "error: Metis Meet requires macOS 15 or later." >&2
  exit 1
fi

if [[ "$(uname -m)" != "arm64" ]]; then
  echo "error: This prebuilt release targets Apple Silicon (arm64). Build from source for Intel." >&2
  exit 1
fi

TMP_DIR="$(mktemp -d /tmp/metismeet-install.XXXXXX)"
cleanup() { rm -rf "$TMP_DIR"; }
trap cleanup EXIT

echo "==> Downloading Metis Meet $VERSION ($ARCHIVE_URL)"
curl -fsSL "$ARCHIVE_URL" -o "$TMP_DIR/MetisMeet.zip"

echo "==> Verifying SHA-256 checksum"
ACTUAL_SHA256="$(shasum -a 256 "$TMP_DIR/MetisMeet.zip" | awk '{print $1}')"
if [[ "$ACTUAL_SHA256" != "$EXPECTED_SHA256" ]]; then
  echo "error: SHA-256 mismatch! Expected $EXPECTED_SHA256, got $ACTUAL_SHA256" >&2
  exit 1
fi

echo "==> Extracting $APP_NAME"
ditto -x -k "$TMP_DIR/MetisMeet.zip" "$TMP_DIR/unpacked"
xattr -dr com.apple.quarantine "$TMP_DIR/unpacked/$APP_NAME" 2>/dev/null || true

DEST="/Applications"
[[ -w "$DEST" ]] || DEST="$HOME/Applications"
mkdir -p "$DEST"

pkill -x "MeetingRecorder" 2>/dev/null && sleep 1 || true
rm -rf "$DEST/$APP_NAME"
cp -R "$TMP_DIR/unpacked/$APP_NAME" "$DEST/$APP_NAME"

echo "==> Installed to $DEST/$APP_NAME"
echo "    Open it with: open \"$DEST/$APP_NAME\""
echo "    Start or stop recording anywhere: Control-Option-Command-R"
echo "    Ask for a live Q&A hint anywhere: Control-Option-Command-A"
